จอ OLED สร้างหน้าปัดมิเตอร์ ด้วย ESP32

/*
 * โค้ดตัวอย่างนี Devadiy สร้างขึ้นเพื่อการเรียนรู้และการพัฒนาโครงการอิเล็กทรอนิกส์แบบเปิด (Open Source) 
 * โดยทุกคนสามารถใช้งานเนื้อหานี้ได้ฟรี เพื่อประโยชน์ส่วนตัวหรือการศึกษา
 * ขอบคุณที่สนใจและสนับสนุน www.devadiy.com
 */

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128  // ความกว้างของจอ OLED
#define SCREEN_HEIGHT 64  // ความสูงของจอ OLED
#define OLED_RESET -1     // ไม่มีพินรีเซ็ต
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

int meterValue = 0; // ค่ามิเตอร์

void setup() {
  Serial.begin(9600);
  
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {  // ที่อยู่ I2C ของจอ OLED
    Serial.println(F("SSD1306 allocation failed"));
  }
  
  display.clearDisplay();
}

void loop() {
  // จำลองค่ามิเตอร์จาก 0 ถึง 180
  meterValue = analogRead(4) / 22.75; // อ่านค่าและปรับให้อยู่ในช่วง 0-180
  
  display.clearDisplay();           // ล้างหน้าจอก่อนวาดใหม่
  drawMeter(meterValue);            // วาดหน้าปัดมิเตอร์พร้อมสเกล
  display.display();                // แสดงผลบนจอ
  
  delay(100);
}

void drawMeter(int value) {
  // วาดวงกลมหน้าปัด
  for (int r = 30; r > 28; r--) {
    display.drawCircle(44, 48, r, SSD1306_WHITE); // วงกลมหลักสำหรับหน้าปัด
  }
  display.fillCircle(44, 48, 2, SSD1306_WHITE);   // จุดศูนย์กลางของหน้าปัด
  
  display.fillRect(0, 55, 75, 10, SSD1306_BLACK); // วาดแถบทึบลบครึ่งวงกลมด้านล่าง

  // วาดสเกล 0, 90, 180
  drawScale();

  // วาดเข็มตามค่ามิเตอร์
  float angle = map(value, 0, 180, -180, 0);  // คำนวณมุมของเข็ม
  float radian = angle * PI / 180;

  // คำนวณตำแหน่งปลายเข็ม
  int x1 = 44 + (22 * cos(radian));
  int y1 = 48 + (22 * sin(radian));
  
  // วาดเข็ม
  display.drawLine(45, 48, x1, y1, SSD1306_WHITE);

  // แสดงค่าตัวเลขด้านล่างของหน้าจอ
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(90, 11);
  display.print("Value: ");
  display.setCursor(105, 23);
  display.print(value);
}

void drawScale() {
  // สร้างสเกลตัวเลข 0, 30, 60, 90, 120, 150, 180 รอบหน้าปัด
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);

  // สเกล 0 
  display.setCursor(4, 48);
  display.print("0");

  // สเกล 30 
  display.setCursor(3, 28);
  display.print("30");

  // สเกล 60 
  display.setCursor(19, 11);
  display.print("60");

  // สเกล 90 
  display.setCursor(40, 6);
  display.print("90");

  // สเกล 120 
  display.setCursor(62, 11);
  display.print("120");

  // สเกล 150 
  display.setCursor(75, 28);
  display.print("150");

  // สเกล 180 
  display.setCursor(80, 48);
  display.print("180");

  // วาดขีดสเกลย่อยทุกๆ 15 หน่วย
  for (int i = 0; i <= 12; i++) { // 180 / 15 = 12 ช่อง
    float angle = map(i * 15, 0, 180, -180, 0);  // กำหนดมุมของแต่ละสเกลย่อย
    float radian = angle * PI / 180;
    
    int x_start = 44 + (24 * cos(radian));
    int y_start = 48 + (24 * sin(radian));
    int x_end = 44 + (26 * cos(radian));
    int y_end = 48 + (26 * sin(radian));
    
    display.drawLine(x_start, y_start, x_end, y_end, SSD1306_WHITE);
  }
}