ArduinoJson คืออะไร? วิธีใช้งานไลบรารี JSON กับ ESP32 และ Arduino IDE

#include <WiFi.h>
#include <AsyncTCP.h>
#include <ESPAsyncWebServer.h>
#include <ArduinoJson.h>

const char* ssid = "YOUR_WIFI";
const char* pass = "YOUR_PASSWORD";

AsyncWebServer server(80);
AsyncWebSocket ws("/ws");

const int RELAY_PUMP = 5;     // ต่อรีเลย์ที่ GPIO5
bool pumpOn = false;

unsigned long lastSend = 0;

void broadcastSensor() {
  // mock sensor
  float temp = 28.5;
  int humi   = 60;
  int soil   = 430;

  StaticJsonDocument<160> doc;
  doc["temp"] = temp;
  doc["humi"] = humi;
  doc["soil"] = soil;
  doc["pump"] = pumpOn;

  String out;
  serializeJson(doc, out);
  ws.textAll(out);
}

void handleIncomingJson(void *arg, uint8_t *data, size_t len) {
  // data เป็นสตริง JSON จากแอป
  StaticJsonDocument<160> doc;
  DeserializationError err = deserializeJson(doc, data, len);
  if (err) return;

  const char* device = doc["device"]; // "pump1"
  const char* action = doc["action"]; // "on"/"off"

  if (device && strcmp(device, "pump1") == 0 && action) {
    pumpOn = (strcmp(action, "on") == 0);
    digitalWrite(RELAY_PUMP, pumpOn ? LOW : HIGH); // Active LOW
  }
}

void onWsEvent(AsyncWebSocket       *server,
               AsyncWebSocketClient *client,
               AwsEventType          type,
               void                 *arg,
               uint8_t              *data,
               size_t                len) {
  if (type == WS_EVT_CONNECT) {
    Serial.printf("WS connect: %u\n", client->id());
  } else if (type == WS_EVT_DATA) {
    AwsFrameInfo * info = (AwsFrameInfo*)arg;
    if (info->final && info->index == 0 && info->len == len && info->opcode == WS_TEXT) {
      handleIncomingJson(arg, data, len);
    }
  } else if (type == WS_EVT_DISCONNECT) {
    Serial.printf("WS disconnect: %u\n", client->id());
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(RELAY_PUMP, OUTPUT);
  digitalWrite(RELAY_PUMP, HIGH); // ปิดไว้ก่อน (Active LOW)

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, pass);
  Serial.print("WiFi connecting");
  while (WiFi.status() != WL_CONNECTED) { delay(500); Serial.print("."); }
  Serial.println("\nWiFi connected: " + WiFi.localIP().toString());

  ws.onEvent(onWsEvent);
  server.addHandler(&ws);

  // หน้า root แบบง่าย ๆ
  server.on("/", HTTP_GET, [](AsyncWebServerRequest *req){
    req->send(200, "text/plain", "ESP32 WebSocket ready: ws://<ip>/ws");
  });

  server.begin();
}

void loop() {
  // ส่งสถานะ/เซนเซอร์ทุก 2 วินาที
  if (millis() - lastSend > 2000) {
    lastSend = millis();
    broadcastSensor();
  }
}