การสร้างระบบแจ้งเตือนเมื่อมีการเคลื่อนไหวด้วย ESP32, IR Sensor และ WebSocket

#include <WiFi.h>
#include <ESPAsyncWebServer.h>
#include <AsyncTCP.h>
#include <ArduinoJson.h>
#include "index.h"
#include "styles.h"
#include "script.h"

// กำหนดค่า Wi-Fi
const char* ssid = "ชื่อเครือข่าย";
const char* password = "รหัสผ่าน";

// ขาของ IR Sensor เชื่อมต่อกับขา GPIO 
const int irSensorPin = 25;
// ขา+ ของ Buzzer เชื่อมต่อกับขา GPIO 
const int buzzerPin = 14;

AsyncWebServer server(80);
AsyncWebSocket ws("/ws");

void notifyClients() {
  StaticJsonDocument<200> doc;
  doc["message"] = "Motion Detected!!";
  String jsonString;
  serializeJson(doc, jsonString);
  ws.textAll(jsonString);
}

void handleWebSocketMessage(void *arg, uint8_t *data, size_t len) {
  AwsFrameInfo *info = (AwsFrameInfo*)arg;
  if(info->final && info->index == 0 && info->len == len && info->opcode == WS_TEXT) {
    data[len] = 0;
    Serial.printf("Received message: %s\n", data);
  }
}

void onEvent(AsyncWebSocket *server, AsyncWebSocketClient *client, AwsEventType type, void *arg, uint8_t *data, size_t len) {
  switch (type) {
    case WS_EVT_CONNECT:
      Serial.println("WebSocket client connected");
      break;
    case WS_EVT_DISCONNECT:
      Serial.println("WebSocket client disconnected");
      break;
    case WS_EVT_DATA:
      handleWebSocketMessage(arg, data, len);
      break;
    case WS_EVT_PONG:
    case WS_EVT_ERROR:
      break;
  }
}

void setup() {
  Serial.begin(115200);

   // เชื่อมต่อ Wi-Fi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("Connected to WiFi");
  Serial.print("Local ESP32 IP: ");
  Serial.println(WiFi.localIP());

  // กำหนดค่า IR Sensor
  pinMode(irSensorPin, INPUT);
  
  // กำหนดค่า Buzzer 
  pinMode(buzzerPin, OUTPUT);
  
  // เริ่มต้น WebSocket server
  ws.onEvent(onEvent);
  server.addHandler(&ws);

  // คำร้องขอ root url HTML
  server.on("/", HTTP_GET, [](AsyncWebServerRequest * request) {
    request->send_P(200, "text/html", index_html);
  });
  // คำร้องขอ style.css
  server.on("/style.css", HTTP_GET, [](AsyncWebServerRequest * request) {
    request->send_P(200, "text/css", style_css);
  });
  // คำร้องขอ script.js
  server.on("/script.js", HTTP_GET, [](AsyncWebServerRequest * request) {
    request->send_P(200, "text/javascript", script_js);
  });
  
  // เริ่มต้น HTTP server
  server.begin();
}

void loop() {
  if (digitalRead(irSensorPin) == LOW) {
    Serial.println("Motion Detected!");
    digitalWrite(buzzerPin, HIGH);
    notifyClients();    
    delay(1000); // หลีกเลี่ยงการแจ้งเตือนซ้ำซ้อน
  }
  else {
    digitalWrite(buzzerPin, LOW);
  }
  ws.cleanupClients();
}